Форум русскоязычного сообщества Ubuntu


За новостями русскоязычного сообщества и Ubuntu в целом можно следить на нашей страничке в Google+

Автор Тема: несколько вопросов по настройке yeahconsole + urxvt  (Прочитано 300 раз)

0 Пользователей и 1 Гость просматривают эту тему.

Оффлайн chadwick

  • Автор темы
  • Новичок
  • *
  • Сообщений: 45
    • Просмотр профиля
ubuntu 14.04 32-bit + openbox
yeahconsole 0.3.4-2.1ubuntu1
urxvt 9.19-1

1) yeahconsole отказывается нормально работать с расширением tabbedex (брал отсюда https://github.com/shaggytwodope/tabbedex-urxvt), вместо панели вкладок отображается фиолетовая полоска, при этом сами вкладки открываются/закрываются; с предустановленным расширением tabbed работает без проблем, но хотелось бы именно tabbedex (сам urxvt нормально работает с tabbedex)

2) мне нужно, чтобы yeahconsole разворачивалась на весь экран; параметром consoleHeight подогнать не получается, в ~/.config/openbox/rc.xml есть такая запись:
<application name="urxvt">
  <maximized>true</maximized>
</application>
но работает это только для urxvt

команда:
obxprop | grep "^_OB_APP"вообще никак не определяет yeahconsole

3) как сделать, чтобы все внешние команды выполнялись в новой вкладке уже запущенной yeahconsole? то есть yeahconsole работает, выполняю внешне (из другого терминала, из меню  или из rofi):
yeahconsole -e alsamixer...и ничего не происходит

то же самое касается и urxvt: если выполнить внешне urxvt -e alsamixer, то откроется еще один urxvt, а мне нужно, чтобы команды выполнялись в новых вкладках

Xresources >>
(Нажмите, чтобы показать/скрыть)

буду признателен за любую помощь

Оффлайн skybour

  • Старожил
  • *
  • Сообщений: 2208
    • Просмотр профиля
Может быть проблема в yeahconsole?

Оффлайн peregrine

  • FSM
  • СуперМодератор
  • Старожил
  • *
  • Сообщений: 6906
  • Gentoo x64 Ubuntu 16.04.1 x64
    • Просмотр профиля
chadwick, последний раз я правил tabbedex, т.к. он был для старой версии, не знаю, может автор сам уже поправил. Но мой выглядит так
Код: Perl
  1. #! perl
  2. # This program is free software: you can redistribute it and/or modify
  3. # it under the terms of the GNU General Public License as published by
  4. # the Free Software Foundation, either version 3 of the License, or
  5. # (at your option) any later version.
  6.  
  7. # This program is distributed in the hope that it will be useful,
  8. # but WITHOUT ANY WARRANTY; without even the implied warranty of
  9. # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  10. # GNU General Public License for more details.
  11.  
  12. # You should have received a copy of the GNU General Public License
  13. # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  14. #
  15. ##
  16. ## Tabbed plugin for rxvt-unicode
  17. ## Modified by Michal Nazarewicz (mina86/AT/mina86.com), StephenB
  18. ## (mail4stb/AT/gmail.com), Steven Merrill
  19. ## <steven dot merrill at gmail.com>, Mark Pustjens
  20. ## <pustjens@dds.nl> and more...
  21. ##
  22. ## The following has been added:
  23. ##
  24. ## 1. Depending on time of last activity, activity character differs.
  25. ##    By default, after 4 seconds an asterisk becomes a plus sing,
  26. ##    after next 4 it becomes a colon, and finally, after another 8
  27. ##    seconds it becomes a dot.  This can be configured via
  28. ##    tabbar-timeouts resource.  It's format is:
  29. ##
  30. ##      ( <timeout> ":" <character> ":" )* <timeout> ":" <character> ":"
  31. ##
  32. ##    where <timeout> is timeout in seconds and <character> is
  33. ##    a single activity character.
  34. ##
  35. ## 2. The "[NEW]" button can be disabled (who on Earth uses mouse to
  36. ##    create new tab anyways?) by setting new-button resource to yes.
  37. ##
  38. ## 3. If title resource is true, tab's title is displayed after last
  39. ##    button.  This is handy if you have terminal with no window
  40. ##    decorations.  Colours can be configured via title-fg and
  41. ##    title-bg.
  42. ##
  43. ## 4. Incorporated Alexey Semenko <asemenko at gmail.com> patch adding
  44. ##    autohide resource.  If it's true tab bar is hidden if there is
  45. ##    no more then one tab opened.
  46. ##
  47. ## 5. Tabs are indexed in starting with zero hex. :] If you're such
  48. ##    a geek to use urxvt it shouldn't be a problem for you and it
  49. ##    saves few character when many tabs are opened.
  50. ##
  51. ## 6. As a minor modification: Final pipe character is removed (unless
  52. ##    title is displayed).  This make tab bar look nicer.
  53. ##
  54. ## Added by StephenB:
  55. ##
  56. ## 7. Tabs can be named with Shift+Up (Enter to confirm, Escape to
  57. ##    cancel).
  58. ##
  59. ## 8. "[NEW]" button disabled by default.
  60. ##
  61. ## Added by Steven Merrill <steven dot merrill at gmail.com>
  62. ##
  63. ## 9. Ability to start a new tab or cycle through tabs via user
  64. ##    commands: tabbedex:(new|next|prev)_tab .
  65. ##    e.g. (in .Xdefaults) URxvt.keysym.M-t: perl:tabbedex:new_tab
  66. ##    (see the urxvt man file for more info about keysym)
  67. ##
  68. ## 10. Fix an issue whereby on_user_command would not properly get sent
  69. ##     to other extension packages if the mouse was not over the urxvt
  70. ##     window.
  71. ##
  72. ## Added by Thomas Jost:
  73. ##
  74. ## 11. Add several user commands: tabbedex:rename_tab,
  75. ##     tabbedex:move_tab_(left|right).
  76. ##     e.g. (see 9.) URxvt.keysym.C-S-Left: perl:tabbex:move_tab_left
  77. ##
  78. ## 12. Ability to disable the default keybindings using the
  79. ##     no-tabbedex-keys resource.
  80. ##
  81. ## Added by xanf (Illya Klymov):
  82. ##
  83. ## 13. Ability to display non-latin characters in tab title.
  84. ##
  85. ## Added by jpkotta:
  86. ##
  87. ## 14. Tabs inherit command line options.
  88. ##
  89. ## Added by Mark Pustjens <pustjens@dds.nl>
  90. ##
  91. ## 15. Resources are now read respecting the -name option.
  92. ##
  93. ## 16. Ability to prevent the last tab from closing.
  94. ##     Use the following in your ~/.Xdefaults to enable:
  95. ##     URXvt.tabbed.reopen-on-close: yes
  96. ##
  97.  
  98. use Encode qw(decode);
  99.  
  100. sub update_autohide {
  101.    my ($self, $reconfigure) = @_;
  102.    my $oldh = $self->{tabheight};
  103.    if ($self->{autohide} && @{ $self->{tabs} } <= 1 &&
  104.          ! (@{ $self->{tabs} } == 1 && $self->{tabs}[-1]->{name})) {
  105.       $self->{tabheight} = 0;
  106.    } else {
  107.       $self->{tabheight} = $self->{maxtabheight};
  108.    }
  109.    if ($reconfigure && $self->{tabheight} != $oldh) {
  110.       $self->configure;
  111.       $self->copy_properties;
  112.    }
  113. }
  114.  
  115.  
  116. sub tab_activity_mark ($$) {
  117.    my ($self, $tab) = @_;
  118.    return ' ' unless defined $tab->{lastActivity};
  119.    return ' ' if $tab == $self->{cur};
  120.    if (defined $self->{timeouts}) {
  121.       my $diff = int urxvt::NOW - $tab->{lastActivity};
  122.       for my $spec (@{ $self->{timeouts} }) {
  123.          return $spec->[1] if $diff > $spec->[0];
  124.       }
  125.    }
  126.    '*';
  127. }
  128.  
  129.  
  130. sub refresh {
  131.    my ($self) = @_;
  132.  
  133.    # autohide makes it zero
  134.    return unless $self->{tabheight};
  135.  
  136.    my $ncol = $self->ncol;
  137.  
  138.    my $text = " " x $ncol;
  139.    my $rend = [($self->{rs_tabbar}) x $ncol];
  140.  
  141.    my ($ofs, $idx, @ofs) = (0, 0);
  142.  
  143.    if ($self->{new_button}) {
  144.       substr $text, 0, 7, "[NEW] |";
  145.       @$rend[0 .. 5] = ($self->{rs_tab}) x 6;
  146.       push @ofs, [0, 6, -1 ];
  147.       $ofs = 7;
  148.    }
  149.  
  150.    for my $tab (@{ $self->{tabs} }) {
  151.       my $name = $tab->{name} ? $tab->{name} : $idx;
  152.       my $act = $self->tab_activity_mark($tab);
  153.       my $txt = sprintf "%s%s%s", $act, $name, $act;
  154.       my $len = length $txt;
  155.  
  156.       substr $text, $ofs, $len + 1, "$txt|";
  157.       @$rend[$ofs .. $ofs + $len - 1] = ($self->{rs_tab}) x $len
  158.          if $tab == $self->{cur};
  159.  
  160.       push @ofs, [ $ofs, $ofs + $len, $idx ];
  161.       ++$idx;
  162.       $ofs += $len + 1;
  163.    }
  164.  
  165.    substr $text, --$ofs, 1, ' '; # remove last '|'
  166.  
  167.    if ($self->{tab_title} && $ofs + 3 < $ncol) {
  168.       my $term = $self->{term};
  169.       my @str = $term->XGetWindowProperty($term->parent, $self->{tab_title});
  170.       if (@str && $str[2]) {
  171.          my $str = '| ' . decode("utf8", $str[2]);
  172.          my $len = length $str;
  173.          $len = $ncol - $ofs if $ofs + $len > $ncol;
  174.          substr $text, $ofs, $len, substr $str, 0, $len;
  175.          @$rend[$ofs + 2 .. $ofs + $len - 1] = ($self->{rs_title}) x ($len - 2);
  176.       }
  177.    }
  178.  
  179.    $self->{tabofs} = \@ofs;
  180.  
  181.    $self->ROW_t (0, $text, 0, 0, $ncol);
  182.    $self->ROW_r (0, $rend, 0, 0, $ncol);
  183.  
  184.    $self->want_refresh;
  185. }
  186.  
  187.  
  188. sub new_tab {
  189.    my ($self, @argv) = @_;
  190.  
  191.    my $offset = $self->fheight;
  192.  
  193.    $self->{tabheight} = $self->{maxtabheight}
  194.    unless $self->{autohide} && !(defined $self->{tabs} && @{ $self->{tabs} });
  195.  
  196.    # save a backlink to us, make sure tabbedex is inactive
  197.    push @urxvt::TERM_INIT, sub {
  198.       my ($term) = @_;
  199.       $term->{parent} = $self;
  200.  
  201.       for (0 .. urxvt::NUM_RESOURCES - 1) {
  202.          my $value = $self->{resource}[$_];
  203.  
  204.          $term->resource ("+$_" => $value)
  205.             if defined $value;
  206.       }
  207.  
  208.       foreach my $opt (keys %urxvt::OPTION) {
  209.           my $value = $self->{option}{$opt};
  210.           $term->option($urxvt::OPTION{$opt}, $value);
  211.       }
  212.  
  213.       $term->resource (perl_ext_2 => $term->resource ("perl_ext_2") . ",-tabbedex");
  214.    };
  215.  
  216.    push @urxvt::TERM_EXT, urxvt::ext::tabbedex::tab::;
  217.  
  218.    my $term = new urxvt::term
  219.       $self->env, $urxvt::RXVTNAME,
  220.       -embed => $self->parent,
  221.       @argv;
  222. }
  223.  
  224.  
  225. sub configure {
  226.    my ($self) = @_;
  227.  
  228.    my $tab = $self->{cur};
  229.  
  230.    # this is an extremely dirty way to force a configurenotify, but who cares
  231.    $tab->XMoveResizeWindow (
  232.       $tab->parent,
  233.       0, $self->{tabheight} + 1,
  234.       $self->width, $self->height - $self->{tabheight}
  235.    );
  236.    $tab->XMoveResizeWindow (
  237.       $tab->parent,
  238.       0, $self->{tabheight},
  239.       $self->width, $self->height - $self->{tabheight}
  240.    );
  241. }
  242.  
  243.  
  244. sub copy_properties {
  245.    my ($self) = @_;
  246.    my $tab = $self->{cur};
  247.  
  248.    my $wm_normal_hints = $self->XInternAtom ("WM_NORMAL_HINTS");
  249.  
  250.    my $current = delete $self->{current_properties};
  251.  
  252.    # pass 1: copy over properties different or nonexisting
  253.    for my $atom ($tab->XListProperties ($tab->parent)) {
  254.       my ($type, $format, $items) = $self->XGetWindowProperty ($tab->parent, $atom);
  255.  
  256.       # fix up size hints
  257.       if ($atom == $wm_normal_hints) {
  258.          my (@hints) = unpack "l!*", $items;
  259.  
  260.          $hints[$_] += $self->{tabheight} for (4, 6, 16);
  261.  
  262.          $items = pack "l!*", @hints;
  263.       }
  264.  
  265.       my $cur = delete $current->{$atom};
  266.  
  267.       # update if changed, we assume empty items and zero type and format will not happen
  268.       $self->XChangeProperty ($self->parent, $atom, $type, $format, $items)
  269.          if $cur->[0] != $type or $cur->[1] != $format or $cur->[2] ne $items;
  270.  
  271.       $self->{current_properties}{$atom} = [$type, $format, $items];
  272.    }
  273.  
  274.    # pass 2, delete all extraneous properties
  275.    $self->XDeleteProperty ($self->parent, $_) for keys %$current;
  276. }
  277.  
  278.  
  279. sub my_resource {
  280.    my $self = shift;
  281.    $self->x_resource ("tabbed.$_[0]");
  282. }
  283.  
  284.  
  285. sub make_current {
  286.    my ($self, $tab) = @_;
  287.  
  288.    if (my $cur = $self->{cur}) {
  289.       delete $cur->{lastActivity};
  290.       $cur->XUnmapWindow ($cur->parent) if $cur->mapped;
  291.       $cur->focus_out;
  292.    }
  293.  
  294.    $self->{cur} = $tab;
  295.  
  296.    $self->configure;
  297.    $self->copy_properties;
  298.  
  299.    $tab->focus_out; # just in case, should be a nop
  300.    $tab->focus_in if $self->focus;
  301.  
  302.    $tab->XMapWindow ($tab->parent);
  303.    delete $tab->{lastActivity};
  304.    $self->refresh;
  305.  
  306.    ();
  307. }
  308.  
  309.  
  310. sub on_focus_in {
  311.    my ($self, $event) = @_;
  312.    $self->{cur}->focus_in;
  313.    ();
  314. }
  315.  
  316. sub on_focus_out {
  317.    my ($self, $event) = @_;
  318.    $self->{cur}->focus_out;
  319.    ();
  320. }
  321.  
  322. sub on_key_press {
  323.    my ($self, $event) = @_;
  324.    $self->{cur}->key_press ($event->{state}, $event->{keycode}, $event->{time});
  325.    1;
  326. }
  327.  
  328. sub on_key_release {
  329.    my ($self, $event) = @_;
  330.    $self->{cur}->key_release ($event->{state}, $event->{keycode}, $event->{time});
  331.    1;
  332. }
  333.  
  334. sub on_button_release {
  335.    my ($self, $event) = @_;
  336.  
  337.    if ($event->{row} == 0) {
  338.       my $col = $event->{col};
  339.       for my $button (@{ $self->{tabofs} }) {
  340.          last if     $col <  $button->[0];
  341.          next unless $col <= $button->[1];
  342.          if ($button->[2] == -1) {
  343.             $self->new_tab;
  344.          } else {
  345.             $self->make_current($self->{tabs}[$button->[2]]);
  346.          }
  347.       }
  348.       return 1;
  349.    }
  350.  
  351.    ();
  352. }
  353.  
  354. sub on_init {
  355.    my ($self) = @_;
  356.  
  357.    $self->{resource} = [map $self->resource ("+$_"), 0 .. urxvt::NUM_RESOURCES - 1];
  358.  
  359.    $self->resource (int_bwidth => 0);
  360.    $self->resource (pty_fd => -1);
  361.  
  362.    $self->{option} = {};
  363.    for my $key (keys %urxvt::OPTION) {
  364.        $self->{option}{$key} = $self->option($urxvt::OPTION{$key});
  365.    }
  366.  
  367.    # this is for the tabs terminal; order is important
  368.    $self->option ($urxvt::OPTION{scrollBar}, 0);
  369.  
  370.    my $fg    = $self->my_resource ("tabbar-fg");
  371.    my $bg    = $self->my_resource ("tabbar-bg");
  372.    my $tabfg = $self->my_resource ("tab-fg");
  373.    my $tabbg = $self->my_resource ("tab-bg");
  374.    my $titfg = $self->my_resource ("title-fg");
  375.    my $titbg = $self->my_resource ("title-bg");
  376.  
  377.    defined $fg    or $fg    = 3;
  378.    defined $bg    or $bg    = 0;
  379.    defined $tabfg or $tabfg = 0;
  380.    defined $tabbg or $tabbg = 1;
  381.    defined $titfg or $titfg = 2;
  382.    defined $titbg or $titbg = 0;
  383.  
  384.    $self->{rs_tabbar} = urxvt::SET_COLOR (urxvt::DEFAULT_RSTYLE, $fg    + 2, $bg    + 2);
  385.    $self->{rs_tab}    = urxvt::SET_COLOR (urxvt::DEFAULT_RSTYLE, $tabfg + 2, $tabbg + 2);
  386.    $self->{rs_title}  = urxvt::SET_COLOR (urxvt::DEFAULT_RSTYLE, $titfg + 2, $titbg + 2);
  387.  
  388.  
  389.    my $timeouts = $self->my_resource ("tabbar-timeouts");
  390.    $timeouts = '16:.:8:::4:+' unless defined $timeouts;
  391.    if ($timeouts ne '') {
  392.       my @timeouts;
  393.       while ($timeouts =~ /^(\d+):(.)(?::(.*))?$/) {
  394.          push @timeouts, [ int $1, $2 ];
  395.          $timeouts = defined $3 ? $3 : '';
  396.       }
  397.       if (@timeouts) {
  398.          $self->{timeouts} = [ sort { $b->[0] <=> $a-> [0] } @timeouts ];
  399.       }
  400.    }
  401.  
  402.    $self->{new_button} =
  403.       ($self->my_resource ('new-button') or 'false') !~ /^(?:false|0|no)/i;
  404.    $self->{tab_title} =
  405.       ($self->my_resource ('title') or 'true') !~ /^(?:false|0|no)/i;
  406.    $self->{autohide} =
  407.       ($self->my_resource ('autohide') or 'false') !~ /^(?:false|0|no)/i;
  408.    $self->{no_default_keys} =
  409.       ($self->my_resource ('no-tabbedex-keys') or 'false') !~ /^(?:false|0|no)/i;
  410.     $self->{reopen_on_close} =
  411.       ($self->my_resource ('reopen-on-close') or 'false') !~ /^(?:false|0|no)/i;
  412.  
  413.    ();
  414. }
  415.  
  416.  
  417. sub on_start {
  418.    my ($self) = @_;
  419.  
  420.    $self->{maxtabheight} = $self->int_bwidth + $self->fheight + $self->lineSpace;
  421.    $self->{tabheight} = $self->{autohide} ? 0 : $self->{maxtabheight};
  422.  
  423.    $self->{running_user_command} = 0;
  424.  
  425.    $self->cmd_parse ("\033[?25l");
  426.  
  427.    my @argv = $self->argv;
  428.  
  429.    do {
  430.       shift @argv;
  431.    } while @argv && $argv[0] ne "-e";
  432.  
  433.    if ($self->{tab_title}) {
  434.       $self->{tab_title} = $self->{term}->XInternAtom("_NET_WM_NAME", 1);
  435.    }
  436.  
  437.    $self->new_tab (@argv);
  438.  
  439.    if (defined $self->{timeouts}) {
  440.       my $interval = ($self->{timeouts}[@{ $self->{timeouts} } - 1]->[0]);
  441.       $interval = int($interval / 4);
  442.       $self->{timer} = urxvt::timer->new
  443.                                    ->interval($interval < 1 ? 1 : $interval)
  444.                                    ->cb ( sub { $self->refresh; } );
  445.    }
  446.  
  447.    ();
  448. }
  449.  
  450.  
  451. sub on_configure_notify {
  452.    my ($self, $event) = @_;
  453.  
  454.    $self->configure;
  455.    $self->refresh;
  456.  
  457.    ();
  458. }
  459.  
  460.  
  461. sub on_user_command {
  462.   my ($self, $event) = @_;
  463.  
  464.   $self->{cur}->{term}->{parent}->tab_user_command($self->{cur}, $event, 1);
  465.  
  466.   ();
  467. }
  468.  
  469.  
  470. sub on_wm_delete_window {
  471.    my ($self) = @_;
  472.    $_->destroy for @{ $self->{tabs} };
  473.    1;
  474. }
  475.  
  476.  
  477. sub tab_start {
  478.    my ($self, $tab) = @_;
  479.  
  480.    $tab->XChangeInput ($tab->parent, urxvt::PropertyChangeMask);
  481.  
  482.    push @{ $self->{tabs} }, $tab;
  483.  
  484. #   $tab->{name} ||= scalar @{ $self->{tabs} };
  485.    $self->make_current ($tab);
  486.  
  487.    ();
  488. }
  489.  
  490.  
  491. sub tab_destroy {
  492.    my ($self, $tab) = @_;
  493.  
  494.    if ($self->{reopen_on_close} && $#{ $self->{tabs} } == 0) {
  495.       $self->new_tab;
  496.       $self->make_current ($self->{tabs}[-1]);
  497.    }
  498.  
  499.    $self->{tabs} = [ grep $_ != $tab, @{ $self->{tabs} } ];
  500.    $self->update_autohide ();
  501.  
  502.    if (@{ $self->{tabs} }) {
  503.       if ($self->{cur} == $tab) {
  504.          delete $self->{cur};
  505.          $self->make_current ($self->{tabs}[-1]);
  506.       } else {
  507.          $self->refresh;
  508.       }
  509.    } else {
  510.       # delay destruction a tiny bit
  511.       $self->{destroy} = urxvt::iw->new->start->cb (sub { $self->destroy });
  512.    }
  513.  
  514.    ();
  515. }
  516.  
  517.  
  518. sub tab_key_press {
  519.    my ($self, $tab, $event, $keysym, $str) = @_;
  520.  
  521.    if ($tab->{is_inputting_name}) {
  522.       if ($keysym == 0xff0d || $keysym == 0xff8d) { # enter
  523.          $tab->{name} = $tab->{new_name};
  524.          $tab->{is_inputting_name} = 0;
  525.          $self->update_autohide (1);
  526.       } elsif ($keysym == 0xff1b) { # escape
  527.          $tab->{name} = $tab->{old_name};
  528.          $tab->{is_inputting_name} = 0;
  529.          $self->update_autohide (1);
  530.       } elsif ($keysym == 0xff08) { # backspace
  531.          substr $tab->{new_name}, -1, 1, "";
  532.          $tab->{name} = "$tab->{new_name}█";
  533.       } elsif ($str !~ /[\x00-\x1f\x80-\xaf]/) {
  534.          $tab->{new_name} .= $str;
  535.          $tab->{name} = "$tab->{new_name}█";
  536.       }
  537.       $self->refresh;
  538.       return 1;
  539.    }
  540.  
  541.    return () if ($self->{no_default_keys});
  542.  
  543.    if ($event->{state} & urxvt::ShiftMask) {
  544.       if ($keysym == 0xff51 || $keysym == 0xff53) {
  545.          if (@{ $self->{tabs} } > 1) {
  546.             $self->change_tab($tab, $keysym - 0xff52);
  547.          }
  548.          return 1;
  549.  
  550.       } elsif ($keysym == 0xff54) {
  551.          $self->new_tab;
  552.          return 1;
  553.  
  554.       } elsif ($keysym == 0xff52) {
  555.          $self->rename_tab($tab);
  556.          return 1;
  557.       }
  558.    } elsif ($event->{state} & urxvt::ControlMask) {
  559.       if ($keysym == 0xff51 || $keysym == 0xff53) {
  560.          $self->move_tab($tab, $keysym - 0xff52);
  561.          return 1;
  562.       }
  563.    }
  564.  
  565.    ();
  566. }
  567.  
  568.  
  569. sub tab_property_notify {
  570.    my ($self, $tab, $event) = @_;
  571.  
  572.    $self->copy_properties
  573.       if $event->{window} == $tab->parent;
  574.  
  575.    ();
  576. }
  577.  
  578.  
  579. sub tab_add_lines {
  580.    my ($self, $tab) = @_;
  581.    my $mark = $self->tab_activity_mark($tab);
  582.    $tab->{lastActivity} = int urxvt::NOW;
  583.    $self->refresh if $mark ne $self->tab_activity_mark($tab);
  584.    ();
  585. }
  586.  
  587.  
  588. sub tab_user_command {
  589.   my ($self, $tab, $cmd, $proxy_events) = @_;
  590.  
  591.   if ($cmd eq 'tabbedex:new_tab') {
  592.     $self->new_tab;
  593.   }
  594.   elsif ($cmd eq 'tabbedex:next_tab') {
  595.     $self->change_tab($tab, 1);
  596.   }
  597.   elsif ($cmd eq 'tabbedex:prev_tab') {
  598.     $self->change_tab($tab, -1);
  599.   }
  600.   elsif ($cmd eq 'tabbedex:move_tab_left') {
  601.     $self->move_tab($tab, -1);
  602.   }
  603.   elsif ($cmd eq 'tabbedex:move_tab_right') {
  604.     $self->move_tab($tab, 1);
  605.   }
  606.   elsif ($cmd eq 'tabbedex:rename_tab') {
  607.     $self->rename_tab($tab);
  608.   }
  609.   else {
  610.     # Proxy the user command through to the tab's term, while taking care not
  611.     # to get caught in an infinite loop.
  612.     if ($proxy_events && $self->{running_user_command} == 0) {
  613.       $self->{running_user_command} = 1;
  614.       urxvt::invoke($tab->{term}, 20, $cmd);
  615.       $self->{running_user_command} = 0;
  616.     }
  617.   }
  618.  
  619.   ();
  620. }
  621.  
  622. sub change_tab {
  623.   my ($self, $tab, $direction) = @_;
  624.  
  625.   my $idx = 0;
  626.   ++$idx while $self->{tabs}[$idx] != $tab;
  627.   $idx += $direction;
  628.   $self->make_current ($self->{tabs}[$idx % @{ $self->{tabs}}]);
  629.  
  630.   ();
  631. }
  632.  
  633. sub move_tab {
  634.   my ($self, $tab, $direction) = @_;
  635.  
  636.   if (@{ $self->{tabs} } > 1) {
  637.     my $idx1 = 0;
  638.     ++$idx1 while $self->{tabs}[$idx1] != $tab;
  639.     my $idx2 = ($idx1 + $direction) % @{ $self->{tabs} };
  640.  
  641.     ($self->{tabs}[$idx1], $self->{tabs}[$idx2]) =
  642.       ($self->{tabs}[$idx2], $self->{tabs}[$idx1]);
  643.     $self->make_current ($self->{tabs}[$idx2]);
  644.   }
  645.  
  646.   ();
  647. }
  648.  
  649. sub rename_tab {
  650.   my ($self, $tab) = @_;
  651.  
  652.   $tab->{is_inputting_name} = 1;
  653.   $tab->{old_name} = $tab->{name} ? $tab->{name} : "";
  654.   $tab->{new_name} = "";
  655.   $tab->{name} = "█";
  656.   $self->update_autohide (1);
  657.   $self->refresh;
  658.  
  659.   ();
  660. }
  661.  
  662. package urxvt::ext::tabbedex::tab;
  663.  
  664. # helper extension implementing the subwindows of a tabbed terminal.
  665. # simply proxies all interesting calls back to the tabbedex class.
  666.  
  667. {
  668.    for my $hook (qw(start destroy user_command key_press property_notify add_lines)) {
  669.       eval qq{
  670.          sub on_$hook {
  671.             my \$parent = \$_[0]{term}{parent}
  672.                or return;
  673.             \$parent->tab_$hook (\@_)
  674.          }
  675.       };
  676.       die if $@;
  677.    }
  678. }

Оффлайн chadwick

  • Автор темы
  • Новичок
  • *
  • Сообщений: 45
    • Просмотр профиля
peregrine, большое спасибо, с вашим вариантом работает

Оффлайн chadwick

  • Автор темы
  • Новичок
  • *
  • Сообщений: 45
    • Просмотр профиля
заменил yeahconsole вот на такой скрипт >>
#!/bin/sh
# quake_rxvt: emulates quake terminal functionality
# designed for use with openbox and wmctrl
# make sure wmctrl is installed

quake_rxvt_wmclass=quake_urxvt

# make sure wmctrl exists
wmctrlpath="$( which wmctrl &>/dev/null )"
if ! [ -x "$wmctrlpath" ] ; then
    echo Error: required dependency wmctrl not found. >&2
    exit 1
fi

active_window_id=\
"$(xprop -root | sed -n -e '/^_NET_ACTIVE/s/^[[:print:]]\{40\}//p')"

# test: true if active window has WM_CLASS $quake_rxvt_wmclass
if xprop -id "$active_window_id" 2>/dev/null | \
    grep -q '^WM_CLASS(STRING)[[:print:]]*'"$quake_rxvt_wmclass"
then
    # hide active quake rxvt
    wmctrl -i -r "$active_window_id" -b add,hidden
elif ! wmctrl -R $quake_rxvt_wmclass -x ; then
# use the wmctrl to both focus and raise quake terminal as well as
# test if it is already running; wmctrl returns nonzero/false if no matching
# window is found, so we have to start it
    urxvt -name $quake_rxvt_wmclass &
fi

и добавил в ~/.config/openbox/rc.xml >>
    <keybind key="A-t">
      <action name="Execute">
        <command>~/.config/urxvt/quake_urxvt.sh</command>
      </action>
    </keybind>

    <application name="quake_urxvt">
      <maximized>true</maximized>
      <focus>yes</focus>
    </application>

таким образом вопрос с масштабированием на весь экран тоже решился

осталось только разобраться с выполнением внешних команд >
urxvt -name quake_urxvt -e [command]> в новой вкладке уже открытого терминала и запретить запуск более одного urxvt

 

Страница сгенерирована за 2.346 секунд. Запросов: 23.